WinBatch Scripting - One Line Functions

• WinBatch One Line Functions
  • IsAlpha (Checks a string for alpha chars only)
  • FileRootExt (Extracts the "Filename.Ext" part of a PathString)
  • AddBackslash (Adds a backslash at end of a string if there is no backslash)
  • ByteToHex (Converts byte value to hexstring)
  • File_Extract_Line (Extract a line from textfile)
  • File_Line_No (Count lines from textfile)
  • StrTrimL (Remove leading blanks from string)
  • StrTrimR (Remove trailing blanks from string)

StrTrimL
StrTrimR

S=" asdf "

; StrTrimL
; Remove leading blanks.
; Steffen Fraas.
L=StrClean(StrTrim(StrCat(S,Num2Char(1))),Num2Char(1),"",@TRUE,1)

; StrTrimR
; Remove trailing blanks.
; Steffen Fraas.
R=StrClean(StrTrim(StrCat(Num2Char(1),S)),Num2Char(1),"",@TRUE,1)


; StrTrimL
; Remove leading blanks.
; Detlev Dalitz.
L=ItemExtract(1,StrTrim(StrCat(S,Num2Char(1))),Num2Char(1))

; StrTrimR
; Remove trailing blanks.
; Detlev Dalitz.
R=ItemExtract(2,StrTrim(StrCat(Num2Char(1),S)),Num2Char(1))


; StrTrimL
; Remove leading blanks.
L=StrSub(S,StrIndex(S,StrTrim(S),0,@FWDSCAN),-1)

; StrTrimR
; Remove trailing blanks.
R=StrSub(S,1,StrIndex(S,StrTrim(S),0,@FWDSCAN)+StrLen(StrTrim(S))-1)

Exit

File_Line_No
File_Extract_Line

; FileLineNo(filename) - number of lines in a file
; FileExtractLine(filename,linenumber) - extract line x from file

; File to test.
x=StrCat(DirHome(),"wsp-user.mnu")

; Line to extract.
y=79


; FileLineNo
; Steffen Fraas.
File_Line_No=ItemCount(StrSub(FileGet(x),1,StrLen(FileGet(x))-2),@CR)

; FileExtractLine
; Steffen Fraas.
File_Extract_Line=StrClean(ItemExtract(y,FileGet(x),@CR),@LF,"",@TRUE,1)

Message(File_Line_No,File_Extract_Line)


; FileLineNo
; Detlev Dalitz.
File_Line_No=ItemCount(FileGet(x),@LF)-(StrSub(FileGet(x),FileSize(x),1)==@LF)

; FileExtractLine
; Detlev Dalitz.
File_Extract_Line=ItemExtract(1,ItemExtract(y,FileGet(x),@LF),@CR)

Message(File_Line_No,File_Extract_Line)


; FileLineNo
; Marty Williams.
File_Line_No=FileSize(x)-StrLen(StrReplace(FileGet(x),@LF,""))

Message(File_Line_No,"")

Exit

ByteToHex

iByte = 221

; input Byte = 0..255 ; returns uppercase HexChars = "0123456789ABCDEF"
ByteToHexU = StrCat(Num2Char((iByte>>4)+48+7*((iByte>>4)>9)),Num2Char((iByte&15)+48+7*((iByte&15)>9)))

; input Byte = 0..255 ; returns lowercase HexChars = "0123456789abcdef"
ByteToHexL = StrCat(Num2Char((iByte>>4)+48+39*((iByte>>4)>9)),Num2Char((iByte&15)+48+39*((iByte&15)>9)))

Exit

AddBackslash

; AddBackslash
; Adds a backslash at end of a string if there is no backslash.

S="test"
If (StrSub(S,StrLen(S),1)!="\") Then S=StrCat(S,"\")
Message("",S)

S="test\"
If (StrSub(S,StrLen(S),1)!="\") Then S=StrCat(S,"\")
Message("",S)

Exit

FileRootExt

; FileRootExt(sURL)  ==> "FILENAME.EXT"

sURL = "\\SERVER\SHARE\FOLDER\FILENAME.EXT"
sURL = "D:\FOLDER\FILENAME.EXT"
sURL = "D:FILENAME.EXT"

sFileRootExt1 = StrCat(FileRoot(sURL),".",FileExtension(sURL))
sFileRootExt2 = StrReplace(sURL,FilePath(sURL),"")
sFileRootExt3 = ItemExtract(-1,ItemExtract(-1,sURL,":"),"\") ; Fastest method.

Exit

IsAlpha

; This one line function "IsAlpha" returns a boolean value,
; which indicates if the given sString contains only alpha characters or not.
; 'Alpha characters' is the char set of [a-zA-Z].

iIsAlpha = ((""!=sString)&&(""==StrClean(StrLower(sString),"esdiltnmarcpohfguwbxkyvjqz","",@TRUE,1)))

Exit