udfArrayQuickSortR
arr udfArrayQuickSortRV1 (arr)
arr udfArrayQuickSortRV2 (arr)
;------------------------------------------------------------------------------------------------------------------------------------------
#DefineFunction udfArrayQuickSortRV1 (arrArray) ; Recursive QuickSort.
If !ArrInfo (arrArray, -1) Then Return ArrDimension (0) ; Invalid input array, return empty valid dim-0 array.
If ArrInfo (arrArray, 0) != 1 Then Return ArrDimension (0) ; Only dim-1 array allowed, return empty valid dim-0 array.
intElements = ArrInfo (arrArray, 1)
If intElements == 0 Then Return ArrDimension (0) ; Input array has no elements, return empty valid dim-0 array.
If intElements == 1 Then Return arrArray ; Input array has only one element, return the input array.
intHigh = intElements - 1
intLow = 0
arrArray = udfArrayQSortRV1 (arrArray, intLow, intHigh) ; Call the recursive part.
Return arrArray
#EndFunction

#DefineFunction udfArrayQSortRV1 (arrArray, intLow, intHigh)
; This function "udfArrayQSortR" should be called first only from inner "udfArrayQuickSortR" or by itself!
If intLow < intHigh
   anyPivot = arrArray [ (intLow + intHigh) / 2]
   intL = intLow
   intR = intHigh
   While (intL <= intR)
      While arrArray [intL] < anyPivot
         intL = intL + 1
      EndWhile
      While anyPivot < arrArray [intR]
         intR = intR - 1
      EndWhile
      If intL <= intR
         anyValue = arrArray [intL]
         arrArray [intL] = arrArray [intR]
         arrArray [intR] = anyValue
         intL = intL + 1
         intR = intR - 1
      EndIf
   EndWhile
   udfArrayQSortRV1 (arrArray, intLow, intR)
   udfArrayQSortRV1 (arrArray, intL, intHigh)
EndIf
Return arrArray
#EndFunction
;------------------------------------------------------------------------------------------------------------------------------------------


;------------------------------------------------------------------------------------------------------------------------------------------
#DefineFunction udfArrayQuickSortRV2 (arrArray) ; Recursive QuickSort.
If !ArrInfo (arrArray, -1) Then Return ArrDimension (0) ; Invalid input array, return empty valid dim-0 array.
If ArrInfo (arrArray, 0) != 1 Then Return ArrDimension (0) ; Only dim-1 array allowed, return empty valid dim-0 array.
intElements = ArrInfo (arrArray, 1)
If intElements == 0 Then Return ArrDimension (0) ; Input array has no elements, return empty valid dim-0 array.
If intElements == 1 Then Return arrArray ; Input array has only one element, return the input array.
intHigh = intElements - 1
intLow = 0
arrArray = udfArrayQSortRV2 (arrArray, intLow, intHigh) ; Call the recursive part.
Return arrArray
#EndFunction

#DefineFunction udfArrayQSortRV2 (arrArray, intLow, intHigh)
; This function "udfArrayQSortR" should be called first only from inner "udfArrayQuickSortR" or by itself!
If intLow < intHigh
   anyPivot = arrArray [ (intLow + intHigh) / 2]
   intL = intLow
   intR = intHigh
   While (intL <= intR)
      While arrArray [intL] < anyPivot
         intL = intL + 1
      EndWhile
      While anyPivot < arrArray [intR]
         intR = intR - 1
      EndWhile
      If intL <= intR
         ArraySwapElements (arrArray, intL, 0, 0, 0, 0, intR, 0, 0, 0, 0)
         intL = intL + 1
         intR = intR - 1
      EndIf
   EndWhile
   udfArrayQSortRV2 (arrArray, intLow, intR)
   udfArrayQSortRV2 (arrArray, intL, intHigh)
EndIf
Return arrArray
;..........................................................................................................................................
; This UDF "udfArrayQSortR2" needs minimal WinBatch version DLL 5.13bem, first showing up in WB 2007B.
;..........................................................................................................................................
#EndFunction
;------------------------------------------------------------------------------------------------------------------------------------------

;----------------------------------------------------------------------------------------------------------------------
#DefineFunction udfArrayItemize (arrArray, strDelimiter)
If !ArrInfo (arrArray, -1) Then Return "" ; No array.
If !ArrInfo (arrArray, 6) Then Return "" ; No elements.
If ArrInfo (arrArray, 0) > 1 Then Return "" ; Too much dimensions.
strItemList = ""
intHigh = Max (ArrInfo (arrArray, 1) - 1, 0)
intLow = 0
For intElem = intLow To intHigh
   If !!VarType (arrArray [intElem])
      strItemList = ItemInsert (arrArray [intElem], -1, strItemList, strDelimiter)
   Else
      strItemList = ItemInsert ("", -1, strItemList, strDelimiter)
   EndIf
Next
Return strItemList
;----------------------------------------------------------------------------------------------------------------------
; This UDF "udfArrayItemize" converts a given dim-1 array into an itemlist
; with each item separated by delimiter character.
;
; Example: strMyItemList = udfArrayItemize (arrMyArray, @TAB)
; Creates an itemList from array.
;
; Note:
; This UDF supports only dim-1 array.
; An array element which is not initialized has a Vartype=0 (undefined).
; Therefore an empty item will be appended to target itemlist.
;
; Detlev Dalitz.20020718.20090508.
;----------------------------------------------------------------------------------------------------------------------
#EndFunction
;----------------------------------------------------------------------------------------------------------------------


; Test.

strMsgTitle = "Demo: udfArrayQuickSortR (arrArray)"
strMsgText = ""

strDelimiter = ","
strItemList = "22,q,w,e,r,t,T,999,a,s,d,f,1,/z,B5,-196" ; 16 Items.

arrA = Arrayize (strItemList, strDelimiter)
arrB = Arrayize (strItemList, strDelimiter)
arrC = Arrayize (strItemList, strDelimiter)

arrB = udfArrayQuickSortRV1 (arrB)
arrC = udfArrayQuickSortRV2 (arrC)

strMsgText = strMsgText : "Array A: " : @LF : udfArrayItemize (arrA, strDelimiter) : @LF : @LF ; "22,q,w,e,r,t,T,999,a,s,d,f,1,/z,B5,-196"
strMsgText = strMsgText : "Array B sorted: " : @LF : udfArrayItemize (arrB, strDelimiter) : @LF : @LF ; "/z,-196,1,22,999,a,B5,d,e,f,q,r,s,t,T,w"
strMsgText = strMsgText : "Array C sorted: " : @LF : udfArrayItemize (arrC, strDelimiter) : @LF : @LF ; "/z,-196,1,22,999,a,B5,d,e,f,q,r,s,t,T,w"

Message (strMsgTitle, strMsgText)

Exit