;------------------------------------------------------------------------------------------------------------------------------------------
#DefineFunction udfArrayGnomeSort (arrArray)
If !ArrInfo (arrArray, -1) Then Return ArrDimension (0) ; Invalid input array, return empty valid dim-0 array.
If ArrInfo (arrArray, 0) != 1 Then Return ArrDimension (0) ; Only dim-1 array allowed, return empty valid dim-0 array.
intElements = ArrInfo (arrArray, 1)
If intElements == 0 Then Return ArrDimension (0) ; Input array has no elements, return empty valid dim-0 array.
If intElements == 1 Then Return arrArray ; Input array has only one element, return the input array.
intI = 1
While intI < intElements
   If arrArray [intI - 1] <= arrArray [intI]
      intI = intI + 1
   Else
      ArraySwapElements (arrArray, intI, 0, 0, 0, 0, intI - 1, 0, 0, 0, 0)
      intI = Max (1, intI - 1)
   EndIf
EndWhile
Return arrArray
;..........................................................................................................................................
; Gnome Sort - The Simplest Sort Algorithm
; The simplest sort algorithm is not Bubble Sort..., it is not Insertion Sort..., it's Gnome Sort!
; Gnome Sort is based on the technique used by the standard Dutch Garden Gnome (Du.: tuinkabouter).
; Here is how a garden gnome sorts a line of flower pots.
; Basically, he looks at the flower pot next to him and the previous one;
; if they are in the right order he steps one pot forward, otherwise he swaps them and steps one pot backwards.
; Boundary conditions: if there is no previous pot, he steps forwards; if there is no pot next to him, he is done.
; Dick Grune / dick@cs.vu.nl / http://www.cs.vu.nl/~dick/gnomesort.html
;
; Ported and tuned to WinBatch by Detlev Dalitz.20090518.
;..........................................................................................................................................
#EndFunction
;------------------------------------------------------------------------------------------------------------------------------------------

;----------------------------------------------------------------------------------------------------------------------
#DefineFunction udfArrayItemize (arrArray, strDelimiter)
If !ArrInfo (arrArray, -1) Then Return "" ; No array.
If !ArrInfo (arrArray, 6) Then Return "" ; No elements.
If ArrInfo (arrArray, 0) > 1 Then Return "" ; Too much dimensions.
strItemList = ""
intHigh = Max (ArrInfo (arrArray, 1) - 1, 0)
intLow = 0
For intElem = intLow To intHigh
   If !!VarType (arrArray [intElem])
      strItemList = ItemInsert (arrArray [intElem], -1, strItemList, strDelimiter)
   Else
      strItemList = ItemInsert ("", -1, strItemList, strDelimiter)
   EndIf
Next
Return strItemList
;----------------------------------------------------------------------------------------------------------------------
; This UDF "udfArrayItemize" converts a given dim-1 array into an itemlist
; with each item separated by delimiter character.
;
; Example: strMyItemList = udfArrayItemize (arrMyArray, @TAB)
; Creates an itemList from array.
;
; Note:
; This UDF supports only dim-1 array.
; An array element which is not initialized has a Vartype=0 (undefined).
; Therefore an empty item will be appended to target itemlist.
;
; Detlev Dalitz.20020718.20090508.
;----------------------------------------------------------------------------------------------------------------------
#EndFunction
;----------------------------------------------------------------------------------------------------------------------


; Test.

strMsgTitle = "Demo: udfArrayGnomeSort (arrArray)"
strMsgText = ""

strDelimiter = ","
strItemList = "22,q,w,e,r,t,T,999,a,s,d,f,1,/z,B5,-196" ; 16 Items.

arrA = Arrayize (strItemList, strDelimiter)
arrB = Arrayize (strItemList, strDelimiter)

arrB = udfArrayGnomeSort (arrB)

strMsgText = strMsgText : "Array A: " : @LF : udfArrayItemize (arrA, strDelimiter) : @LF : @LF ; "22,q,w,e,r,t,T,999,a,s,d,f,1,/z,B5,-196"
strMsgText = strMsgText : "Array B sorted: " : @LF : udfArrayItemize (arrB, strDelimiter) : @LF : @LF ; "/z,-196,1,22,999,a,B5,d,e,f,q,r,s,t,T,w"

Message (strMsgTitle, strMsgText)

Exit