;==========================================================================================================================================
;
; How to mass replace 'inner text' in specific keys in XML file? (3)
;
; The 'DOM Extender' Version.
;
; (c)Detlev Dalitz.20111219.
;==========================================================================================================================================

;-----------------------------------------------------
;   Ini file "Config.ini".
;
;   [IniFilePass]
;   C01_01=Pass
;   C01_02=Pass
;   C01_03=Pass
;   C01_04=Pass
;   D01_02=Pass
;   D01_03=Not Reporting
;   D01_04=Not Reporting
;   D01_05=Pass
;   E01_01=Pass
;   E01_02=Pass
;   E01_03=Confidential - Not Provided
;   E01_04=Pass
;   E01_05=Pass
;   E01_06=Pass
;   E01_07=Pass
;   E01_08=Not Reporting - Privileged Information
;   E01_09=Pass
;   E01_10=Pass
;-----------------------------------------------------

; Define working folder.
strFolderHome = DirScript ()
DirChange (strFolderHome)

; Define data file pathes.
strFileIni = strFolderHome : "Config.ini"
strFileXmlIn = strFolderHome : "Data.in.xml"
strFileXmlOut = strFolderHome : "Data.out.xml"

; For sure, remove existing output file.
If 0 != FileExist (strFileXmlOut) Then FileDelete (strFileXmlOut)


; Load the 3rdParty DOM extender, made by Jennifer Palonus, Graphical Dynamics, http://autointern.bestmessageboard.com
AddExtender ("WxDOM44i.dll")

; Read XML file into DOM buffer.
hdlDocXml = DOMParseFile (strFileXmlIn, @DOMDocXML, @DOMAuto)

; Open ini file and walk through the items.
strIniSection = "IniFilePass"
strListItems = IniItemizePvt (strIniSection, strFileIni)
intItems = ItemCount (strListItems, @TAB)
For intI = 1 To intItems
   strKey = ItemExtract (intI, strListItems, @TAB)
   strValue = IniReadPvt (strIniSection, strKey, "Pass", strFileIni)
   If strValue == "Pass" Then Continue

   ; Do the replacements.
   arrNodes = Arrayize (DOMGetElementsByTagname (hdlDocXml, strKey), @TAB)
   intNodeLast = ArrInfo (arrNodes, 1) - 1
   For intNode = 0 To intNodeLast
      blnResult = DOMSetInnerHTML (arrNodes[intNode], strValue, @TRUE)
   Next
Next

; Write DOM buffer to disk file.
blnResult = DOMWriteFile (hdlDocXml, strFileXmlOut, @DOMAuto)

; Close DOM buffer.
hdlDocXml = DOMClose (hdlDocXml)

; If this script has been called from another WB script, then return to the caller from here ...
If RtStatus () != 10 Then If IntControl (77, 80, 0, 0, 0) > 0 Then Return ; ... when not in WinBatch Studio debug mode.

; Display result.
ShellExecute (strFileXmlOut, "", "", @NORMAL, "")

:CANCEL
Exit